Module GPS

[Papa Charlie]

Un encodeur (comme le CTS288 vendu par Opencockpits) permet aussi d'envoyer des équivalents clavier. J'ai déjà expérimenté et cela fonctionne très bien.
Voir ici pour un exemple : http://www.lekseecon.nl/howto.html#QNH
Philippe


EDIT : petite précision : j'ai expérimenté avec les IOcards, pas avec les cartes de Leo Bodnard...

[nonolight]

Il est très bien ce petit lien Bien qu'il soit en anglais .

Nono

[Papa Charlie]

Oui, Nico Kaan est très doué niveau programmation SIOC. J'ai appris plein de choses en regardant son site...
Philippe

[Papa Charlie]

Pour utiliser en réel un GPS Garmin 296 (portable) on retrouve pas mal de fonction identique.

Moi, en réel, j'utilise un PDA avec le logiciel NAVI (voir ici : http://www.navi-ulm.com/).
Logiciel gratuit, évolutif, et très bien réalisé. D'ailleurs, des pilotes avion l'utilisent également.
J'ai essayé de le relier à FS9 via GPSout (application de Peter Dowson), sans succès.
Apparemment, certains ont réussi avec FSConnect, mais ce dernier ne fonctionne qu'avec FSX.
C'est vrai qu'utiliser en simulation le même matériel qu'en réel permet de "se faire la main" en toute sécurité.
Mais je ne désespère pas d'y arriver...
Philippe

[steph737]

Un encodeur (comme le CTS288 vendu par Opencockpits) permet aussi d'envoyer des équivalents clavier. J'ai déjà expérimenté et cela fonctionne très bien.

Bien sur ça ne pose aucun problème sous SIOC. Le programme sioc du MCP Opencockpit pour le pmdg par exemple est fortement basé la-dessus. C'est juste que je trouve la programmation par offsets plus "propre" que l'émulation clavier ( qui impose de bien faire gaffe entre les listes de caractères utilisés dans sioc.ini, l'assignation dans FS, celle de certains addons qui ont leur menu particulier, les fichiers ini de reality XP ( voire une reprise sous autohotkey si besoin, sachant que certaines combinaisons de touches - forcément nécessaires vu le nombre - ne sont pas possible suivant tel ou tel logiciel ).

Mais l'essentiel est d'avoir une solution valide.

[nonolight]

Y a t-il actuellement d'autres GPS pour FS simulaires à GNS de RealityXP où l'on puisse afficher facilement que l'écran ?

Nono

[Papa Charlie]

Pas à ma connaissance. Il me semble me souvenir d'un logiciel qui faisait en même temps radar météo, mais qui a disparu de la circulation (en tout cas le site n'existe plus).
Et vous, les autres membres du forum, des idées ?
Philippe

[steph737]

http://www.fs2x.com/Freeware.htm mais pas sur qu'il offre beaucoup plus de fonction que le GPS natif voire moins. Sur ce site il y a également un GPS KLN 90B ( le même que celui dans le B200 ) avec plus de fonctions. (payware)

[Boutondair]

Pour un GPS sur un PDA, Filipo avait réussi, voici son tuto http://www.f-bmpl.com/index.php?option= ... &Itemid=28

J'ai déjà essayer mais je n'ai pas réussi mais je vais retenter quand j'aurais le temps

à bientôt,

David

[nonolight]

Sur ce site il y a également un GPS KLN 90B ( le même que celui dans le B200 ) avec plus de fonctions.

Le 530 serait plus adapté pour mon Bell.
Le GNS de RealityXP est sauf erreur de ma part entièrement paramètré via Sioc :
http://www.simforums.com/forums/forum_p ... ?TID=11260
Voici son code, vous pouvez me le confirmer ? :

Code: Tout sélectionner

// *****************************************************************************
// * Config_SIOC ver 3.5   -     By Manolo Vélez    -    www.opencockpits.com
// *****************************************************************************
// * FileName : GPS.txt
// * Date : 08/10/2009



Var 0030, name radio1_1, Link IOCARD_OUT, Output 95     // radio 1/1 led

Var 0031, name radio1_2, Link IOCARD_OUT, Output 94     // radio 1/2 led

Var 0032, name radio1dp, Link IOCARD_OUT, Output 93     // radio 1dp led

Var 0033, name radio2_1, Link IOCARD_OUT, Output 98     // radio 2/1 led

Var 0034, name radio2_2, Link IOCARD_OUT, Output 97     // radio 2/2 led

Var 0035, name radio2dp, Link IOCARD_OUT, Output 96     // radio 2dp led

Var 0036, name radio3_1, Link IOCARD_OUT, Output 103     // radio 3/1 led

Var 0037, name radio3_2, Link IOCARD_OUT, Output 104     // radio 3/2 led

Var 0038, name radio3dp, Link IOCARD_OUT, Output 105     // radio 3dp led

Var 0039, name radio4_1, Link IOCARD_OUT, Output 106     // radio 4/1 led

Var 0040, name radio4_2, Link IOCARD_OUT, Output 107     // radio 4/2 led

Var 0041, name radio4dp, Link IOCARD_OUT, Output 108     // radio 4dp led

Var 0042, name adfdp, Link IOCARD_OUT, Output 31     // adf dp

Var 0043, name dme_NM, Link IOCARD_OUT, Output 75     // dme NM led

Var 0044, name dme_KT, Link IOCARD_OUT, Output 76     // dme KT led

Var 0045, name dme_MIN, Link IOCARD_OUT, Output 78     // dme MIN led

Var 0046, name adf2dp, Link IOCARD_OUT, Output 42     // adf 2 dp

Var 0047, name DMEdp, Link IOCARD_OUT, Output 79     // dme dp

Var 0000, name INITIZATION, Value 0     // initization
{
  &radio1_1 = 1   
  &radio1_2 = 1   
  &radio1dp = 1   
  &radio2_1 = 1   
  &radio2_2 = 1   
  &radio2dp = 1   
  &radio3_1 = 1   
  &radio3_2 = 1   
  &radio3dp = 1   
  &radio4_1 = 1   
  &radio4_2 = 1   
  &radio4dp = 1   
  &adfdp = 1   
  &dme_NM = 1   
  &dme_KT = 1   
  &dme_MIN = 1   
  &DMEdp = 1   
  &adf2dp = 1   
}

Var 0100, name Outer, Link FSUIPC_INOUT, Offset $0BB0, Length 2     // outer maker

Var 0111, name out_outmark, Link IOCARD_OUT, Output 19     // Led Outer Marker
{
  &Outer = &out_outmark   
}

Var 0112, name fs_midmark, Link FSUIPC_INOUT, Offset $0BAE, Length 2     // Offset Middle Marker

Var 0113, name out_midmark, Link IOCARD_OUT, Output 20     // Led Middle Marker
{
  &fs_midmark = &out_midmark   
}

Var 0114, name fs_inmark, Link FSUIPC_INOUT, Offset $0BAC, Length 2     // Offset Inner Marker

Var 0115, name out_inmark, Link IOCARD_OUT, Output 21     // Led Inner Marker
{
  &fs_inmark = &out_inmark   
}

Var 0118, Link IOCARD_OUT, Output 11     // COM1 Audio

Var 0119, Link IOCARD_OUT, Output 12     // COM2 Audio

Var 0120, Link IOCARD_OUT, Output 13     // BOTH Audio

Var 0121, Link IOCARD_OUT, Output 14     // AUX Audio

Var 0122, Link IOCARD_OUT, Output 15     // NAV1 Audio

Var 0123, Link IOCARD_OUT, Output 16     // NAV2 Audio

Var 0124, Link IOCARD_OUT, Output 17     // MKR Audio

Var 0125, Link IOCARD_OUT, Output 22     // ADF Audio

Var 0126, Link FSUIPC_IN, Offset $3122, Length 1     // Radio Audio Bytes
{
  V0118 = TESTBIT V0126 ,7     // COM1
  V0119 = TESTBIT V0126 ,6     // COM2
  V0120 = TESTBIT V0126 ,5     // BOTH
  V0122 = TESTBIT V0126 ,4     // NAV1
  V0123 = TESTBIT V0126 ,3     // NAV2
  V0124 = TESTBIT V0126 ,2     // MRKR
  V0125 = TESTBIT V0126 ,0     // ADF
}

Var 0127, Link FSUIPC_OUT, Offset $3122, Length 1     // Radio Audio Bytes

Var 0128, Link IOCARD_SW, Input 99, Type P     // COM1 Audio
{
  V0127 = SETBIT 7
  V0127 = CLEARBIT 6
}

Var 0129, Link IOCARD_SW, Input 105, Type P     // COM2 Audio
{
  V0127 = SETBIT 6
  V0127 = CLEARBIT 7
}

Var 0130, Link IOCARD_SW, Input 107, Type P     // BOTH Audio
{
  V0127 = CHANGEBIT 5 ,V0130
}

Var 0131, Link IOCARD_SW, Input 104, Type P     // NAV1 Audio
{
  V0127 = CHANGEBIT 4 ,V0131
}

Var 0132, Link IOCARD_SW, Input 102, Type P     // NAV2 Audio
{
  V0127 = CHANGEBIT 3 ,V0132
}

Var 0133, Link IOCARD_SW, Input 103, Type P     // MKR Audio
{
  V0127 = CHANGEBIT 2 ,V0133
}

Var 0134, Link IOCARD_SW, Input 100, Type P     // ADF Audio
{
  V0127 = CHANGEBIT 0 ,V0134
}

Var 0140, Link KEYS

Var 0141, Link IOCARD_SW, Input 72
{
  V0140 = V0141 * 1
}

Var 0142, Link IOCARD_SW, Input 80
{
  V0140 = V0142 * 2
}

Var 0143, Link IOCARD_SW, Input 79
{
  V0140 = V0143 * 3
}

Var 0144, Link IOCARD_SW, Input 78
{
  V0140 = V0144 * 4
}

Var 0145, Link IOCARD_SW, Input 87
{
  V0140 = V0145 * 5
}

Var 0146, Link IOCARD_SW, Input 88
{
  V0140 = V0146 * 6
}

Var 0147, Link IOCARD_SW, Input 84
{
  V0140 = V0147 * 7
}

Var 0148, Link IOCARD_SW, Input 83
{
  V0140 = V0148 * 8
}

Var 0149, Link IOCARD_SW, Input 81
{
  V0140 = V0149 * 9
}

Var 0150, Link IOCARD_SW, Input 95
{
  V0140 = V0150 * 10
}

Var 0151, Link IOCARD_SW, Input 90
{
  V0140 = V0151 * 11
}

Var 0152, Link IOCARD_SW, Input 98
{
  V0140 = V0152 * 12
}

Var 0153, Link IOCARD_SW, Input 91
{
  V0140 = V0153 * 14
}

Var 0154, Link IOCARD_SW, Input 94
{
  V0140 = V0154 * 13
}

Var 0155, Link IOCARD_ENCODER, Input 92, Aceleration 1, Type 2
{
  IF V0155 < 0     // up
  {
    V0140 = 15   
  }
  IF V0155 > 0     // down
  {
    V0140 = 16   
  }
  V0140 = 0   
}

Var 0156, Link IOCARD_ENCODER, Input 74, Aceleration 1, Type 2
{
  IF V0156 < 0     // up
  {
    V0140 = 18   
  }
  IF V0156 > 0     // down
  {
    V0140 = 17   
  }
  V0140 = 0   
}

Var 0157, Link IOCARD_ENCODER, Input 96, Aceleration 1, Type 2
{
  IF V0157 < 0     // up
  {
    V0140 = 20   
  }
  IF V0157 > 0     // down
  {
    V0140 = 19   
  }
  V0140 = 0   
}

Var 0158, Link IOCARD_ENCODER, Input 76, Aceleration 1, Type 2
{
  IF V0158 < 0     // up
  {
    V0140 = 22   
  }
  IF V0158 > 0     // down
  {
    V0140 = 21   
  }
  V0140 = 0   
}

Var 0159, Link IOCARD_SW, Input 73
{
  V0140 = V0159 * 23
}

Var 0160, Link IOCARD_SW, Input 86
{
  V0140 = V0160 * 24
}

Var 0210, name FS_C2_SB_BCD, Link FSUIPC_INOUT, Offset $311C, Length 2     // FS COM2 standby frequency in BCD format

Var 0218, name FS_C2_ACT_BCD, Link FSUIPC_IN, Offset $3118, Length 2     // FS COM2 active frequency in BCD format
{
  &DISP_C2_ACT = FROMBCD &FS_C2_ACT_BCD     // Update C1 active freq display (4 digits)
  CALL &C2_LH_ROT_VAL     // Align rotary with new C1 SB integer val
  CALL &C2_RH_ROT_VAL     // Align rotary with new C1 SB decimal val
  CALL &C2_UPDATE_LHS
  CALL &C2_UPDATE_RHS
}

Var 0219, name FS_C2_SWAP, Link FSUIPC_OUT, Offset $3123, Length 1     // FS COM2 active standby swap

Var 0220, name C2_SB_AS_DEC     // COM2 standby frequency in decimal format

Var 0239, name C2_SB_LHS     // COM2 standby frequency integers

Var 0240, name C2_SB_RHS     // COM2 standby frequency decimals

Var 0241, name C2_RHS_ROT_VAL     // COM2 right hand rotary encoder ref value

Var 0242, name C2_LHS_ROT_VAL     // COM2 left hand rotary encoder ref value

Var 0243, name ROT_C2_LHS, Link IOCARD_ENCODER, Input 69, Aceleration 0
{
  &C2_LHS_ROT_VAL = ROTATE 18 ,36 ,&ROT_C2_LHS
  CALL &C2_UPDATE_LHS
  CALL &SET_FS_C2_SB
}

Var 0244, name ROT_C2_RHS, Link IOCARD_ENCODER, Input 64, Aceleration 2
{
  &C2_RHS_ROT_VAL = ROTATE 0 ,39 ,&ROT_C2_RHS
  CALL &C2_UPDATE_RHS
  CALL &SET_FS_C2_SB
}

Var 0245, name SW_C2_SWAP, Link IOCARD_SW, Input 58
{
  &FS_C2_SWAP = TOGGLE 2
}

Var 0246, name DISP_C2_SB_LHS, Link IOCARD_DISPLAY, Digit 10, Numbers 2     // Standby integers

Var 0247, name DISP_C2_SB_RHS, Link IOCARD_DISPLAY, Digit 8, Numbers 2     // Standby decimals

Var 0248, name DISP_C2_ACT, Link IOCARD_DISPLAY, Digit 12, Numbers 4

Var 0249, name C2_LH_ROT_VAL, Link SUBRUTINE     // Aligns LH rotary ref with COM2 SB freq
{
  L0 = FROMBCD &FS_C2_SB_BCD
  L1 = L0 / 100
  &C2_LHS_ROT_VAL = TRUNC L1
}

Var 0250, name C2_RH_ROT_VAL, Link SUBRUTINE     // Aligns RH rotary ref with COM2 SB freq
{
  L0 = FROMBCD &FS_C2_SB_BCD
  L1 = &C2_LHS_ROT_VAL * 100
  L2 = L0 - L1
  &C2_RHS_ROT_VAL = L2 / 2.487179
}

Var 0251, name C2_UPDATE_LHS, Link SUBRUTINE     // Update COM2 stanby integers
{
  &DISP_C2_SB_LHS = &C2_LHS_ROT_VAL         // Set COM1 standby integer display
  &C2_SB_LHS = &C2_LHS_ROT_VAL   
}

Var 0252, name C2_UPDATE_RHS, Link SUBRUTINE     // Update COM2 standby decimals
{
  L0 = &C2_RHS_ROT_VAL * 2.5
  &C2_SB_RHS = TRUNC L0
  &DISP_C2_SB_RHS = &C2_SB_RHS   
}

Var 0253, name SET_FS_C2_SB, Link SUBRUTINE     // Update COM2 standby frequency in FS
{
  L0 = &C2_SB_LHS * 100
  L1 = L0 + &C2_SB_RHS
  &FS_C2_SB_BCD = TOBCD L1
}

Var 0254, name FS_N2_SB_BCD, Link FSUIPC_INOUT, Offset $3120, Length 2     // FS NAV2 standby frequency in BCD format

Var 0255, name FS_N2_ACT_BCD, Link FSUIPC_IN, Offset $0352, Length 2     // FS NAV2 active frequency in BCD format
{
  &DISP_N2_ACT = FROMBCD &FS_N2_ACT_BCD     // Update N2 active freq display (4 digits)
  CALL &N2_LH_ROT_VAL     // Align rotary with new N2 SB integer val
  CALL &N2_RH_ROT_VAL     // Align rotary with new N2 SB decimal val
  CALL &N2_UPDATE_LHS
  CALL &N2_UPDATE_RHS
}

Var 0256, name FS_N2_SWAP, Link FSUIPC_OUT, Offset $3123, Length 1     // FS NAV2 active standby swap

Var 0258, name N2_SB_AS_DEC     // NAV2 standby frequency in decimal format

Var 0259, name N2_SB_LHS     // NAV2 standby frequency integers

Var 0260, name N2_SB_RHS     // NAV2 standby frequency decimals

Var 0262, name N2_RHS_ROT_VAL     // NAV2 right hand rotary encoder ref value

Var 0264, name N2_LHS_ROT_VAL     // NAV2 left hand rotary encoder ref value

Var 0266, name ROT_N2_LHS, Link IOCARD_ENCODER, Input 60, Aceleration 0
{
  &N2_LHS_ROT_VAL = ROTATE 8 ,17 ,&ROT_N2_LHS
  CALL &N2_UPDATE_LHS
  CALL &SET_FS_N2_SB
}

Var 0268, name ROT_N2_RHS, Link IOCARD_ENCODER, Input 55, Aceleration 0
{
  &N2_RHS_ROT_VAL = ROTATE 0 ,39 ,&ROT_N2_RHS
  CALL &N2_UPDATE_RHS
  CALL &SET_FS_N2_SB
}

Var 0270, name SW_N2_SWAP, Link IOCARD_SW, Input 59
{
  &FS_N2_SWAP = TOGGLE 0
}

Var 0271, name DISP_N2_SB_LHS, Link IOCARD_DISPLAY, Digit 2, Numbers 2     // Standby integers

Var 0272, name DISP_N2_SB_RHS, Link IOCARD_DISPLAY, Digit 0, Numbers 2     // Standby decimals

Var 0273, name DISP_N2_ACT, Link IOCARD_DISPLAY, Digit 4, Numbers 4

Var 0274, name N2_LH_ROT_VAL, Link SUBRUTINE     // Aligns LH rotary ref with NAV2 SB freq
{
  L0 = FROMBCD &FS_N2_SB_BCD
  L1 = L0 / 100
  &N2_LHS_ROT_VAL = TRUNC L1
}

Var 0275, name N2_RH_ROT_VAL, Link SUBRUTINE     // Aligns RH rotary ref with NAV2 SB freq
{
  L0 = FROMBCD &FS_N2_SB_BCD
  L1 = &N2_LHS_ROT_VAL * 100
  L2 = L0 - L1
  &N2_RHS_ROT_VAL = L2 / 2.487179
}

Var 0276, name N2_UPDATE_LHS, Link SUBRUTINE     // Update NAV2 stanby integers
{
  &DISP_N2_SB_LHS = &N2_LHS_ROT_VAL         // Set NAV2 standby integer display
  &N2_SB_LHS = &N2_LHS_ROT_VAL   
}

Var 0278, name N2_UPDATE_RHS, Link SUBRUTINE     // Update NAV2 standby decimals
{
  L0 = &N2_RHS_ROT_VAL * 2.5
  &N2_SB_RHS = TRUNC L0
  &DISP_N2_SB_RHS = &N2_SB_RHS   
}

Var 0280, name SET_FS_N2_SB, Link SUBRUTINE     // Update NAV2 standby frequency in FS
{
  L0 = &N2_SB_LHS * 100
  L1 = L0 + &N2_SB_RHS
  &FS_N2_SB_BCD = TOBCD L1
}

Var 3000, Value 0     // Inicializacion
{
  V0310 = 222         // Inicializamos los 3 digitos ADF1
  V0311 = 0         // Pone 0 fijo frecuencia activa ADF1
  V0313 = 0         // Pone 0 fijo frecuencia standby ADF1
  V0330 = TOBCD 234     // Inicializo frecuencia ADF1 en 234
  &ADFFRQled = 1   
  V0318 = 1         // Inicio LED ACT ADF1
  &ADFBFOled = 1   
  &ADFADFled = 1   
  V0315 = 1         // Inicio LED SB ADF1
}

Var 0310     // Frecuencia standby ADF1
{
  CALL V1104
}

Var 0311, Link IOCARD_DISPLAY, Digit 20, Numbers 1     // Digito bajo frecuencia ADF1 (fijo)

Var 0312, Link IOCARD_DISPLAY, Digit 21, Numbers 3     // Frecuencia ADF1

Var 0313, Link IOCARD_DISPLAY, Digit 16, Numbers 1     // Digito bajo frecuencia stby ADF1 (fijo)

Var 0314, Link IOCARD_DISPLAY, Digit 17, Numbers 3     // Frecuencia standby ADF1

Var 0315, Link IOCARD_OUT, Output 31     // LED_ACT_ADF1

Var 0316, name ADFFRQled, Link IOCARD_OUT, Output 41     // ADF FRQ led

Var 0319, name ADFBFOled, Link IOCARD_OUT, Output 40     // ADF BFO led

Var 0317, name ADFADFled, Link IOCARD_OUT, Output 30     // ADF led

Var 0318, Link IOCARD_OUT, Output 42     // LED SB ADF1

Var 0320, Link IOCARD_ENCODER, Input 19, Aceleration 2     // Encoder para frecuencia ADF1
{
  L0 = V0320 * 1     // Cambia sentido de giro
  V0310 = V0310 - L0
  IF V0310 > 999
  {
    V0310 = 0   
  }
  IF V0310 < 0
  {
    V0310 = 999   
  }
}

Var 0330, Link FSUIPC_OUT, Offset $034C, Length 2     // Frecuencia activa ADF1
{
  L0 = FROMBCD V0330
  V0312 = L0   
}

Var 0073, Link IOCARD_SW, Input 8, Type P     // Pulsador de SWAP ADF1
{
  L0 = V0310         // Monto digitos
  L1 = FROMBCD V0330     // Salvo la frecuencia actual pasando a dec
  V0330 = TOBCD L0     // y se lo paso a la frecuencia de standby
  V0314 = V0310         // Presento la nueva frecuencia
  V0310 = L1   
}

Var 1104, Link SUBRUTINE     // Manda valor a frecuencia standby ADF1
{
  L0 = V0310   
  V0314 = L0   
}

Var 0440, Link IOCARD_DISPLAY, Digit 28, Numbers 3     // altitude

Var 0441, Link FSUIPC_IN, Offset $0EC6, Length 2     // QNH * 16

Var 0442, Link FSUIPC_IN, Offset $6020, Length 8, Numbers 0     // encoded FL
{
  L0 = V0441 / 16     // QNH setting
  L0 = L0 - 1013     // difference to standard pressure
  L0 = L0 * 27     // millibars -> feet in altimeter
  L1 = V0442 * 3.2808399     // meters to feet
  L1 = L1 - L0
  L1 = L1 / 100
  &ALT = TRUNC L1
  CALL &ALTout
}

Var 0450, name TRALTled, Link IOCARD_OUT, Output 34     // ALT led transponder

Var 0451, name TRONled, Link IOCARD_OUT, Output 37     // ON led transponder

Var 0452, name TRSBYled, Link IOCARD_OUT, Output 36     // SBY led  transponder

Var 0453, name TRGNDled, Link IOCARD_OUT, Output 35     // GND led  transponder

Var 0454, Link FSUIPC_IN, Offset $0366, Length 2     // on ground=1
{
  &TRGNDled = V0454   
}

Var 0455, Link FSUIPC_OUT, Offset $7B91, Length 1     // 0=norm, 1=sby (VATSIM)

Var 0456, name STBYsw, Link IOCARD_SW, Input 28     // STBY Switch
{
  IF &STBYsw = 1
  {
    &TRSBYled = 1   
  }
  &TRSBYled = &STBYsw   
}

Var 0457, name TESTsw, Link IOCARD_SW, Input 30     // TEST Switch
{
  IF &TESTsw = 1
  {
    V0455 = 1   
    &XPNDRDISP = -999999   
  }
  ELSE
  {
    CALL &XPNDRCALC
  }
}

Var 0458, name ONsw, Link IOCARD_SW, Input 29     // ON Switch
{
  IF &ONsw = 1
  {
    V0455 = 0   
  }
  &TRONled = &ONsw   
}

Var 0459, name ALTsw, Link IOCARD_SW, Input 31     // ALT Switch
{
  CALL &ALTout
  IF &ALTsw = 1
  {
    V0455 = 0   
  }
  &TRFLled = &ALTsw   
  &TRALTled = &ALTsw   
}

Var 0460, Link FSUIPC_OUT, Offset $7B93, Length 1     // Ident

Var 0461, name IDENTbutt, Link IOCARD_SW, Input 2     // IDENT Button
{
  V0460 = &IDENTbutt   
  IF &IDENTbutt = 1
  {
    IF &TRIDENTled = 0
    {
      &TRIDENTled = 1   
      &TRIDENTled = DELAY 0 ,1000
    }
  }
}

Var 0410, Value 2
{
  CALL &XPNDRCALC
}

Var 0411, Value 0
{
  CALL &XPNDRCALC
}

Var 0412, Value 0
{
  CALL &XPNDRCALC
}

Var 0413, Value 0
{
  CALL &XPNDRCALC
}

Var 0415, name INPXPNDR1000, Link IOCARD_ENCODER, Input 10, Aceleration 0, Type 2     // Input 1000
{
  V0410 = V0410 + &INPXPNDR1000
  V0410 = ROTATE 0 ,7 ,0
}

Var 0416, name INPXPNDR100, Link IOCARD_ENCODER, Input 12, Aceleration 0, Type 2     // Input 100
{
  V0411 = V0411 + &INPXPNDR100
  V0411 = ROTATE 0 ,7 ,0
}

Var 0417, name INPXPNDR10, Link IOCARD_ENCODER, Input 16, Aceleration 0, Type 2     // Input 10
{
  V0412 = V0412 + &INPXPNDR10
  V0412 = ROTATE 0 ,7 ,0
}

Var 0418, name INPXPNDR1, Link IOCARD_ENCODER, Input 14, Aceleration 0, Type 2     // Input 1
{
  V0413 = V0413 + &INPXPNDR1
  V0413 = ROTATE 0 ,7 ,0
}

Var 0425, Link IOCARD_SW, Input 1     // VFR button
{
  &XPNDRDISP = 2000         // VFR Code (CH 7000, USA 1200, Germany 002
  &XPNDRTOFS = TOBCD &XPNDRDISP
}

Var 0426, name XPNDRDISP, Link IOCARD_DISPLAY, Digit 24, Numbers 4     // Display
{
  L0 = &XPNDRDISP   
}

Var 0427, name XPNDRTOFS, Link FSUIPC_INOUT, Offset $0354, Length 2     // XPNDR
{
  L0 = &XPNDRDISP   
}

Var 0428, name XPNDRIN, Value 7000     // XPNDR Input from FS

Var 0430, Link FSUIPC_OUT, Offset $7B93, Length 4     // IDT button for Squawkbox

Var 0434, Link IOCARD_SW, Input 2     // IDT button
{
  V0430 = V0434   
}

Var 0435, name XPNDRCALC, Link SUBRUTINE     // Code calculation
{
  L0 = V0410 * 1000
  L1 = V0411 * 100
  L0 = L0 + L1
  L1 = V0412 * 10
  L0 = L0 + L1
  L0 = L0 + V0413
  &XPNDRTOFS = TOBCD L0
  &XPNDRDISP = L0   
}

Var 0470, name ALT
{
  CALL &ALTout
}

Var 0480, name ALTout, Link SUBRUTINE     // Alt to displays
{
  IF &ALTsw = 1     // ALT on
  {
    V0440 = &ALT         // Blank display
  }
  ELSE
  {
    V0440 = -999999   
  }
}

Var 0482, name TRFLled, Link IOCARD_OUT, Output 33     // Transponder FL led

Var 0483, name TRIDENTled, Link IOCARD_OUT, Output 32     // Transponder ident led

Var 0501, name Dist_1, Link FSUIPC_IN, Offset $0300, Length 2     // DME 1 Input Distance
{
  CALL &CALC_DME1
}

Var 0502, name Speed_1, Link FSUIPC_IN, Offset $0302, Length 2     // DME 1 Input Speed
{
  CALL &CALC_DME1
}

Var 0503, name Time_1, Link FSUIPC_IN, Offset $0304, Length 2     // DME 1 Input Time
{
  CALL &CALC_DME1
}

Var 0504, name Dist_2, Link FSUIPC_IN, Offset $0306, Length 2     // DME 2 Input Distance
{
  CALL &CALC_DME2
}

Var 0505, name Speed_2, Link FSUIPC_IN, Offset $0308, Length 2     // DME 2 Input Speed
{
  CALL &CALC_DME2
}

Var 0506, name Time_2, Link FSUIPC_IN, Offset $030A, Length 2     // DME 2 Input Time
{
  CALL &CALC_DME2
}

Var 0509, name CALC_DME1, Link SUBRUTINE
{
  IF &Dist_1 = 65526
  {
    &Dist_out1 = -999998   
  }
  ELSE
  {
    &Dist_out1 = &Dist_1   
  }
  IF &Speed_1 = -65526
  {
    &Speed_out1 = -999998   
  }
  ELSE
  {
    &Speed_out1 = &Speed_1 / 10
  }
  IF &Time_1 = 9999
  {
    &Time_out1 = -999998   
    CALL &SWITCH
  }
  ELSE
  {
    L1 = &Time_1 / 60
    L1 = L1 / 10
    &Time_out1 = TRUNC L1
    CALL &SWITCH
  }
}

Var 0510, name CALC_DME2, Link SUBRUTINE
{
  IF &Dist_2 = 65526
  {
    &Dist_out2 = -999998   
  }
  ELSE
  {
    &Dist_out2 = &Dist_2   
  }
  IF &Speed_2 = 65526
  {
    &Speed_out2 = -999998   
  }
  ELSE
  {
    &Speed_out2 = &Speed_2 / 10
  }
  IF &Time_2 = 9999
  {
    &Time_out2 = -999998   
    CALL &SWITCH
  }
  ELSE
  {
    L1 = &Time_2 / 60
    L1 = L1 / 10
    &Time_out2 = TRUNC L1
    CALL &SWITCH
  }
}

Var 0511, name DME_SWR, Link IOCARD_SW, Input 36, Type I
{
  IF &DME_SWR = 1
  {
    &DME_TOGGLE = 2   
  }
}

Var 0512, name DME_SWL, Link IOCARD_SW, Input 43, Type I
{
  IF &DME_SWL = 1
  {
    &DME_TOGGLE = 1   
  }
}

Var 0513, name DME_TOGGLE, Link FSUIPC_INOUT, Offset $0378, Length 2

Var 0514, name SWITCH, Link SUBRUTINE
{
  IF &DME_TOGGLE = 1
  {
    &Dist_out = &Dist_out1   
    &Speed_out = &Speed_out1   
    &Time_out = &Time_out1   
  }
  ELSE
  {
    &Dist_out = &Dist_out2   
    &Speed_out = &Speed_out2   
    &Time_out = &Time_out2   
  }
}

Var 0515, name Dist_out, Link IOCARD_DISPLAY, Digit 37, Numbers 4

Var 0516, name Speed_out, Link IOCARD_DISPLAY, Digit 34, Numbers 3

Var 0517, name Time_out, Link IOCARD_DISPLAY, Digit 32, Numbers 2

Var 0518, name Dist_out1

Var 0519, name Speed_out1

Var 0520, name Time_out1

Var 0523, name Dist_out2

Var 0524, name Speed_out2

Var 0525, name Time_out2


A+

Nono