A320 Mix Rudder Trim + Pushback

Radio / Pilote Automatique / FMC CDU, etc...

A320 Mix Rudder Trim + Pushback

Messagede rafphifou » Mer 2 Nov 2016 21:54

Salut,

Comme évoqué en 2015, J'ai utilisé le panel rudder trim pour faire les Pushbacks.
http://www.aircockpit.com/viewtopic.php?f=100&t=4700&hilit=trim+park+brake&start=12

J'ai ajouté un bouton pour le pushback sur le panel:
Image


Principe de fonctionnement
Le rudder trim fonctionne normalement (R20.0 - 00.0 - L20.0)

On souhaite faire un pushback de 75° à Gauche :
> On appuie sur PB
. Le rudder trim est transformé en pushback et " 000" clignote

> On tourne le bouton rudder trim sur LEFT
. Affiché = L015 L030 L045 .... L075

> ( Un message de technicien pourrais nous demander de desserrer les freins )

> On desserre les freins
. le pushback commence et tourne à gauche
. En fonction du cap de l'avion, la valeurs affiché diminue
. Affiché = L075 L074 L073 .... L000
. On peux toujours modifier l'angle avec le bouton rudder trim
. Ou arrêter la rotation avec le bouton Reset

> à 000, le push continue tout droit
. On peut encore tourner avec le bouton rudder trim

> Pour arrêter le pushback on appuie sur PB
. Le rudder trim refonctionne normalement


Image



Le 6 Avr 2015 fab a écrit:Raphael, tu vas décevoir si tu n'y arrives pas ecroulerire

Je dois encore fignoler un peu le code, mais c'est pour bientôt.


A suivre
Raphael
http://rafou.airlines.free.fr/
Dernière édition par rafphifou le Dim 6 Nov 2016 22:16, édité 2 fois.
Avatar de l’utilisateur
rafphifou
 
Messages: 78
Inscription: 18/08/13
Localisation: 91

Re: A320 Mix Rudder Trim + Pushback

Messagede fab » Mer 2 Nov 2016 22:40

Respect m'sieur applaublanc
Belle idée !

Tu trouves où l'info de l'angle de l'avion en push back ?
Avatar de l’utilisateur
fab
 
Messages: 4414
Inscription: 26/12/12
Localisation: Roubaix

Re: A320 Mix Rudder Trim + Pushback

Messagede rafphifou » Mer 2 Nov 2016 23:06

Pour l'angle, j'ai utilisé le cap de l'avion, comme ça l'angle est précit.
Rien de mieux qu'un exemple :

Avant le pushback je suis au cap 180°
Je veux un push à gauche pour 90° ( cap final = 270°)

Valeur affiché = cap final - cap = angle restant
Valeur affiché = 270 -180 = L 090

Pas facile à programmer quand tu passe de 359 à 0, mais ça fonctionne.

Raphaël
Avatar de l’utilisateur
rafphifou
 
Messages: 78
Inscription: 18/08/13
Localisation: 91


Re: A320 Mix Rudder Trim + Pushback

Messagede fab » Jeu 3 Nov 2016 08:21

Super bien pensé !
Avatar de l’utilisateur
fab
 
Messages: 4414
Inscription: 26/12/12
Localisation: Roubaix

Re: A320 Mix Rudder Trim + Pushback

Messagede rafphifou » Sam 5 Nov 2016 13:11

Bonjour,

Une nouvelle vidéo qui explique le fonctionnement :

IL FAUT ACTIVER LES SOUS TITRES

[youtube]https://www.youtube.com/watch?v=_VcP1_Xkjio[/youtube]
https://www.youtube.com/embed/_VcP1_Xkjio

Un dernier détail à régler avant le code sioc...

Raphael
http://rafou.airlines.free.fr/
Dernière édition par rafphifou le Mer 9 Oct 2019 23:18, édité 4 fois.
Avatar de l’utilisateur
rafphifou
 
Messages: 78
Inscription: 18/08/13
Localisation: 91

Re: A320 Mix Rudder Trim + Pushback

Messagede rafphifou » Dim 6 Nov 2016 20:59

Bonsoir,

Après plusieurs tours de terrain en pushback, voilà le SIOC.

J'utilise une carte Open Cockpit USB AXE.
je passe par FSUIPC pour identifier les boutons. Le code est un peu plus compliqué.
Image


Code: Tout sélectionner
//*******  MIX  RUDDER TRIM AND PUSHBACK ****************
Var 5531 name pushtrim_aff link IOCARD_DISPLAY, digit 76, numbers 3   // Display for trim or push angle
Var 5532 name pushtrim_signe link IOCARD_DISPLAY, digit 79, numbers 1 // display L or r (2 or 4)
var 5533 name TrimReset_sw
var 5534 name rudder_lh
var 5536 name rudder_rh
var 5537 name push_sw
var 5538 name fin_rot
var 5539 name Pushback_mode  //  0=mode Trim  1=mode Pushback
Var 5540 name pushing Link FSUIPC_INOUT, Offset $31F4, Length 2 // Pushback FS 0=back, 1=right, 2=left, 3=off
Var 5541 name RUDDERTRIM_FS Link FSUIPC_INOUT Offset $0C04 Length 2  // $0C04  Rudder trim control: –16383 to +16383
Var 5542 name  TRIM_mod Link FSUIPC_INOUT Offset $78ED  Length 2  // $0C04 jeehell Rudder trim control  77=LH  78=RH  79=nil  80=Reset


Var 5543 name parkbrake Link FSUIPC_INOUT, Offset $0BC8 Length 2 // parking brake
{
  if &parkbrake = 0
  {
    if &Pushback_mode = 1 // only when parkbreak unlock
    {
    if &rotat > 0
    {
     &pushing = 1   // start push LH with angle rotat
    }
    if &rotat < 0   
    {
     &pushing = 2  // start push RH with angle rotat
    }
    if &rotat = 0
    {
     &pushing = 0  // start push back
     &rotat = 0
    }
    }
  }
}


// **************** The JOY64 fonction must be done on FSUIPC (for joystic bouton only)******************************************
// **************** Press on JOYSTIC BUTTONS, and select 'setbit' function. exp : setbit 6001  parametre : 0001 


Var 5544 name joy_deux Link FSUIPC_INOUT, Offset $6001, Length 2 // FSUIPC joy64 OC USB AXE buttons
{

&push_sw = TESTBIT &joy_deux ,0  // 0001 = for select pushback or trim

if &push_sw = 1  // pushback mode
  {
  if &Pushback_mode = 1    // If mode pushback active
    {
    &Pushback_mode = 0  // active mode Trim   
    &fin_rot = 0   // reset
    &rotat = 0     // reset
    &pushing = 3  // End of pushback
   

// ****  Display rudder trim value ****
      if &TRIM_FS <= 200  // right   000 à 200
      {
      &pushtrim_signe = 4   // display r
      &pushtrim_aff = &TRIM_FS  // Write trim value  000 a 200
      }   
      if &TRIM_FS > 65330  // right   000 à 200
      {
      &pushtrim_signe = 2   // display L
      L0 = 65536 - &TRIM_FS 
      &pushtrim_aff = L0  // Write trim value  200 a 000
      }

    }
    else   // If mode rudder trim
    {
    &Pushback_mode = 1  //  active mode pushback
    &fin_rot = 0       // reset end of rotat
    &pushtrim_signe = -999999  // display
    &pushtrim_aff = -999999    // display
    }
  }
}

Var 5545 name joy_un Link FSUIPC_INOUT, Offset $6000, Length 4 // FSUIPC joy64   OC USB AXE buttons
{

&rudder_lh = TESTBIT &joy_un,0   // 0001 : button LH
&rudder_rh = TESTBIT &joy_un,1   // 0010 : button RH
&TrimReset_sw = TESTBIT &joy_un,2   // 0100  : button Reset
&TRIM_mod = 79  // jeehell rudder trim = nil

 if &rudder_lh = 1
  {
    if &Pushback_mode = 1  // If mode pushback
    {
   &rotat = &rotat + 30  // increase angle by 30°

        L0 = &heading * 8.3819E-008  // aircraft heading  -180 to  +180
        IF L0 < 0
   {
        L0 = L0 + 360
        }
        L1 = ROUND L0    // aircraft heading  0 to 360

        L2 = L1 + &rotat
   &fin_rot = MOD L2 360   // record heading end of rotate
       
    }
    ELSE   // mode rudder trim
    {
    &TRIM_mod = 77   // jeehell rudder trim
    }
  }


 if &rudder_rh = 1
  {
    if &Pushback_mode = 1   // mode pushback
    {
   &rotat = &rotat - 30  // increase angle by -30°

        L0 = &heading * 8.3819E-008  // aircraft heading  -180 +180
        IF L0 < 0     // convert heading
   {
        L0 = L0 + 360
        }
        L1 = ROUND L0  // aircraft heading  0 360

   L2 = L1 + &rotat
   L2 = L2 + 360
   &fin_rot = MOD L2 360  // record heading end of rotate
    }
    ELSE        // mode rudder trim
    {
    &TRIM_mod = 78   // jeehell rudder trim
    }
  }

  if &TrimReset_sw = 1
  {
    if &Pushback_mode = 1   // mode pushback
    {
      &rotat = 0     // End of rotation
      &fin_rot = 0   // Reset end value heading
      &pushtrim_aff = -999999
      &pushtrim_signe = -999999
    }
    ELSE
    {
    &TRIM_mod = 80 // jeehell rudder trim reset
    }
  }
}


Var 5546 name heading Link FSUIPC_INOUT, Offset $0580, Length 4 // heading from -180 +180
{
    if &Pushback_mode = 1 // mode pushback
    {   
        L0 = &heading * 8.3819E-008  // convert heading to 0-360°
        IF L0 < 0    
   {
        L0 = L0 + 360
        }
        L1 = ROUND L0   // aircraft heading  0 360

   if &rotat < 0  // Push in progress RH
   {
     L2 = &fin_rot - L1  // heading end of rotate  -  Heading
     L2 = 360 - L2
     L2 = MOD L2 360
     &rotat = -1 * L2  // remaning rotation angle
   }

   if &rotat > 0  // Push in progress LH
   {
     L2 =  &fin_rot - L1  // heading end of rotate  -  Heading
     L2 = L2 + 360
     L2 = MOD L2 360
     &rotat = L2   // remaning rotation angle
   }

   if &rotat = 0   //  END OF ROTATION
    {
      &pushtrim_signe = -999999
    &pushing = 0 // normal pushback
        }
    }
}

var 5547 name rotat   // display remaning rotation angle
{
    if &rotat < 0
    {
     &pushtrim_signe = 4    // display "R" on digit
     &pushtrim_aff = ABS &rotat
    }

    if &rotat > 0
    {
     &pushtrim_signe = 2   // display "L" on digit
     &pushtrim_aff = ABS &rotat
    }

    if &rotat = 0
    {
     &pushtrim_signe = -999999
     &pushtrim_aff = 000
     &rotat = 0
    }
}

Var 5548 name TRIM_FS Link FSUIPC_INOUT Offset $73B1  Length 2  // jeehell Rudder trim readonly  LH = 65336 to 65536   RH=0 to 200
{
   if &TRIM_FS <= 200  // RIGHT = 000 à 200
   {
   &pushtrim_signe = 4   // display r
   &pushtrim_aff = &TRIM_FS  // Write trim value  000 a 200


   // FOR OTHER FS AIRCRAFTS
   L0 = L0 * 82
   L0 = ROUND L0
   &RUDDERTRIM_Fs = L0   // RECORD TO FS RUDDER TRIM VALUE 0 +16383
   }
   
  if &TRIM_FS > 65330  // LEFT = 65336 to 65536
   {
   &pushtrim_signe = 2   // display L
   L0 = 65536 - &TRIM_FS 
   &pushtrim_aff = L0  // Write trim value  200 a 000
   
   // FOR OTHER FS AIRCRAFTS
   L0 = L0 * 82
   L0 = ROUND L0
   L0 = -1 * L0
   &RUDDERTRIM_FS = L0   // RECORD TO FS RUDDER TRIM VALUE -16383 0
   }
}



Le PushBack fonctionne avec tous les avions.
Le Rudder trim fonctionne parfaitement avec A320FMGC (Jeehell)

Pour le rudder Trim des autres avions j'ai beaucoup essayé avec les offsets : $0C04 & $2EC0, impossible de modifier la valeur.
Solution : la fonction Keys en Sioc >>> Dans FSUIPC assigner cette touche au Rudder Trim .



Actuellement le pushback est limité à 90° L ou R.
Je vais modifier le code pour ne plus être limité.
Il sera aussi possible de tourner à droite puis à gauche, puis a droite ...

Raphaël
http://rafou.airlines.free.fr/
Avatar de l’utilisateur
rafphifou
 
Messages: 78
Inscription: 18/08/13
Localisation: 91

Re: A320 Mix Rudder Trim + Pushback

Messagede fab » Dim 6 Nov 2016 21:17

y a pas à dire, beau boulot !
Avatar de l’utilisateur
fab
 
Messages: 4414
Inscription: 26/12/12
Localisation: Roubaix

Re: A320 Mix Rudder Trim + Pushback

Messagede Pegase78 » Lun 7 Nov 2016 00:28

Merci pour ce partage Raphaël ! C'est super applaublanc applaublanc applaublanc

Alain
Avatar de l’utilisateur
Pegase78
 
Messages: 184
Inscription: 18/02/16


Retourner vers Modules de "fabrication maison"





Qui est en ligne

Utilisateurs parcourant ce forum: Aucun utilisateur enregistré et 5 invités