Effet de bord non prévu

[Capena]

Bonjour(soir)(nuit)

Je rencontre un problème (encore) inexplicable sur mon montage.

Après avoir changé mes potar modèle barbecue, je rebranche mon pédestral et refait les tests de mon code SIOC.

Les premiers tests dans IOCP Console sont concluants, toutes les variables répondent correctement à mes sollicitations.
Par contre, dans FS (qui est quand même la finalité du truc), dès que je bouge ma commande de gaz, l'axe de pas d’hélice se met en plein grand pas (valeur 0).
du coup je bouge un poil la manette d'hélice et là, la richesse se met à 0

sachant que la commande de richesse n'est pas un axe, mais juste trois inters (modèle pris sur le site de Claude, le beech, j'en profite pour le remercier)

quelqu'un a-t-il une explication à ce phénomène ?
est-ce un problème de programmation ? de branchement ?
est-ce encore le nuage noir qui flotte au dessus de ma tête qui sévit ?

Pour info, lorsque je suis sous FS, je met IOCP Console sur le deuxième écran pour voir, et là effectivement les variables changent d'état toutes seules ... et dès que je quitte FS, plus de problème ..... .
Ma carte Master est alimentée en +5V, le reste des commandes fonctionnent parfaitement bien (Trim profondeur, trim aileron, volets, réservoir), c'est déjà ça

j'ai pas trouvé d’équivalent à ce problème sur ce forum, peut-être sur l'ancien ?

Merci d'avance pour vos réponses ... là je vais me coucher .....

[Capena]

Bon, là j'ai vraiment besoin de comprendre ce qu'il se passe ...

Voici le code (plutôt très simple) :

Code: Tout sélectionner

Var 0000, name INIT     // INIT
{
  &GAZ = 0
}

// ********************** Déclarations Variables ****************************************
Var 0107, name GAZ, Link FSUIPC_INOUT, Offset $088C, Length 4, Value 0     // Commande Gaz
// ********************** Déclarations Variables FIN ****************************************

// ********************** Commandes Vols ****************************************************

Var 1007, name POT_AXE_G, Link IOCARD_ANALOGIC, Input #3, PosL 0, PosC 127, PosR 255     // Axe Gaz
{
  IF &POT_AXE_G <= 8
  {
    &GAZ = 0
  }
  ELSE
  {
    L0 = &POT_AXE_G * 64.25
   IF L0 > 16384
   {
      L0 = 16384
   }
   &GAZ = L0
  }
}

// ********************** Commandes Vols FIN ************************************************

Quand je bouge la manette des Gaz, l’hélice se met plein grand pas .... pourtant il n'y a rien dans Sioc qui commande l’hélice .... et les gaz répondent correctement (c'est déjà ça)

Quand j'utilise FS sans le programme SIOC, pas de problème (j'augmente les gaz avec F3 - F4). l'hélice ne bouge pas

Où est le problème ? Carte défectueuse ? Un paramétrage dans FS caché ? Un bug FSUIPC ?
Personne n'a eu de problème similaire ? ais-je à ce point un manque de chance ?

Pour info, il s'agit de FS2004, fraichement re-installé, sans aucun Add-Ons. Le test est fait sur le Cessna Caravan. FSUIPC 3.98a et aucun Joystick branché.

Vincent

[stevelep]

Hello,

Oui tu as commis une erreur sur la longueur de la variable gaz $088C qui est de Length 2
et non 4.
Comme les offsets sont contigus, en mettant une longueur trop grande tu empiètes sur la
variable suivante qui est le propeller lever (le levier de pas), donc tu perturbes cette variable ...

J'ai rajouté TYPE 1, car l'offset des gaz peux prendre des valeurs négatives (reverse)
Sinon le SIOC ne les reconnait pas.

J'ai utilisé la fonction LIMIT au lieu d'un IF

J'ai enlevé le # au n° d'input du potentiomètre qui n'en prend pas.

Voila

BOB



Var 0000, name INIT // INIT
{
&GAZ = 0
}

// ********************** Déclarations Variables ****************************************
Var 0107, name GAZ, Link FSUIPC_INOUT, Offset $088C, Length 2, Value 0, Type 1 // Commande Gaz
// ********************** Déclarations Variables FIN ****************************************

// ********************** Commandes Vols ****************************************************

Var 1007, name POT_AXE_G, Link IOCARD_ANALOGIC, Input 3, PosL 0, PosC 127, PosR 255 // Axe Gaz
{
IF &POT_AXE_G <= 8
{
&GAZ = 0
}
ELSE
{
L0 = &POT_AXE_G * 64.25
L0 = LIMIT -16384 16384 0
&GAZ = L0
}
}

// ********************** Commandes Vols FIN

[Capena]

ARF !!!
je suis trop nul !! c’était juste ça .....
comme quoi il faut toujours avoir un oeil sur la doc des Offset ...

Un grand merci à toi !! j'aurais pas vu ce détail tout de suite ... ça c'est sur ....



et merci pour les optimisations



Vincent